# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

GUILE_COMPAT=( 3-0 )
NEED_EMACS=28.1
PYTHON_COMPAT=( python3_{12..14} )
inherit elisp-common meson guile-single readme.gentoo-r1 python-any-r1
inherit shell-completion xdg-utils

DESCRIPTION="Set of tools to deal with Maildirs, in particular, searching and indexing"
HOMEPAGE="https://www.djcbsoftware.nl/code/mu/ https://github.com/djcb/mu"
SRC_URI="https://github.com/djcb/mu/releases/download/v${PV}/${P}.tar.xz"

# mu: GPL-3+
# + tl: CC0-1.0
# + variant-lite: Boost-1.0
LICENSE="GPL-3+ BSD Boost-1.0 CC0-1.0 MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~x64-macos"
IUSE="emacs guile readline test"
RESTRICT="!test? ( test )"
REQUIRED_USE="guile? ( ${GUILE_REQUIRED_USE} )"

DEPEND="
	>=dev-cpp/cli11-2.4
	>=dev-libs/glib-2.80:2
	>=dev-libs/gmime-3.2.13:3.0
	>=dev-libs/libfmt-11.1:=
	>=dev-libs/xapian-1.4.22:=
	emacs? ( >=app-editors/emacs-28.1:* )
	guile? ( ${GUILE_DEPS} )
	readline? ( sys-libs/readline:= )
"
RDEPEND="${DEPEND}"
BDEPEND="
	${PYTHON_DEPS}
	>=dev-build/meson-1.3.2
	sys-apps/texinfo
	virtual/pkgconfig
"

DOC_CONTENTS="
	To use mu4e you need to configure it in your .emacs file.
	See the manual for more information:
	https://www.djcbsoftware.nl/code/mu/mu4e/
"
SITEFILE="70mu-gentoo-autoload.el"

pkg_setup() {
	[[ ${MERGE_TYPE} == binary ]] && return

	if use emacs ; then
		elisp-check-emacs-version
	fi

	if use guile; then
		guile-single_pkg_setup
	fi
}

src_prepare() {
	default

	# Don't install NEWS.org into /usr/share/doc.
	sed -i '/NEWS.org/,+1 d' meson.build || die
	sed -i '/mu4e-about.org/d' mu4e/meson.build || die

	# Don't compress the info file.
	sed -i '/gzip/d' build-aux/meson-install-info.sh || die

	# Instead, put it in /usr/share/doc/${PF}.
	sed -i "/MU_DOC_DIR/s/mu/${PF}/" mu4e/meson.build || die
}

src_configure() {
	local emesonargs=(
		$(meson_feature readline)
		$(meson_feature test tests)
		-Dcld2=disabled
		-Demacs="$(usex emacs "${EMACS}" emacs-not-enabled)"
		-Dscm=enabled
		-Dbash-completion=enabled
		-Dbash-completion-dir="$(get_bashcompdir)"
		-Dfish-completion=enabled
		-Dfish-completion-dir="$(get_fishcompdir)"
		-Dzsh-completion=enabled
		-Dzsh-completion-dir="$(get_zshcompdir)"
	)
	meson_src_configure
}

src_install() {
	meson_src_install

	# Since meson no longer installs NEWS.org, install it with dodoc.
	# Also, it must be uncompressed so that it can be viewed with
	# mu4e-info.
	docompress -x /usr/share/doc/${PF}/NEWS.org
	dodoc NEWS.org

	if use emacs; then
		# Same as above.
		docompress -x /usr/share/doc/${PF}/mu4e-about.org
		dodoc mu4e/mu4e-about.org

		elisp-site-file-install "${FILESDIR}"/${SITEFILE}

		readme.gentoo_create_doc
	fi

	use guile && guile_unstrip_ccache
}

pkg_postinst() {
	xdg_icon_cache_update
	use emacs && readme.gentoo_create_doc
}

pkg_postrm() {
	xdg_icon_cache_update
	use emacs && elisp-site-regen
}